武装后勤

一键清理Windows7系统“你的电脑不受支持”提示

微软在2020年1月14日以后将结束对Windows7系统的支持,前期发布的补丁会包含一个如下图的全屏提示。点击“不在提醒我”也可以关闭并且后期不在提示,但残留的文件还存在。通过网络搜索,找到个一键清理的批处理命令,在此做个笔记。(注:从本站下载的Windows7系统已包含此命令)

复制下方命令,新建txt文档,粘贴并另存为.bat或.cmd即可

  1. @ECHO OFF
  2. >NUL 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
  3. IF '%errorlevel%' NEQ '0' (
  4. GOTO UACPrompt
  5. ) ELSE ( GOTO gotAdmin )
  6. :UACPrompt
  7. ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  8. ECHO UAC.ShellExecute "%~s0""""""runas", 1 >> "%temp%\getadmin.vbs"
  9. "%temp%\getadmin.vbs"
  10. EXIT /B
  11. :gotAdmin
  12. IF EXIST "%temp%\getadmin.vbs" ( DEL "%temp%\getadmin.vbs" )
  13. TITLE EOSNotify-清理
  14. CLS
  15. TIMEOUT 3 >NUL
  16. SET winsxs=%SystemRoot%\winsxs
  17. ECHO.
  18. ECHO 清理EOSNotify WinSXS...
  19. FOR /f %%i IN ('dir /b %winsxs%\^|findstr ".*microsoft-windows-eosnotify.*"') DO (
  20. takeown /a /r /d Y /f "%winsxs%\%%i" >NUL
  21. icacls "%winsxs%\%%i" /T /C /grant administrators:D >NUL
  22. ECHO 正在删除WinSXS
  23. ECHO %%i
  24. RMDIR /s /q "%winsxs%\%%i"
  25. )
  26. ECHO.
  27. ECHO 清理EOSNotify manifest...
  28. FOR /f %%i IN ('dir /b %winsxs%\Manifests^|findstr ".*microsoft-windows-eosnotify.*\.manifest"') DO (
  29. takeown /a /f "%winsxs%\Manifests\%%i" >NUL
  30. icacls "%winsxs%\Manifests\%%i" /grant administrators:D >NUL
  31. DEL /F /S /Q "%winsxs%\Manifests\%%i"
  32. )
  33. TIMEOUT 3 >NUL
  34. ECHO.
  35. ECHO 删除EOSNotify 注册表...
  36. FOR /f %%i IN ('REG QUERY HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SideBySide\Winners^|findstr ".*microsoft-windows-eosnotify.*"') DO (
  37. ECHO 正在删除注册表
  38. reg delete %%i /f
  39. )
  40. TIMEOUT 3 >NUL
  41. ECHO.
  42. ECHO 删除EOSNotify计划任务...
  43. schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify" /f
  44. schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify2" /f
  45. TIMEOUT 3 >NUL
  46. IF EXIST "%SystemRoot%\System32\EOSNotify.exe" (
  47. ECHO.
  48. ECHO 删除 EOSNotify.exe 文件...
  49. taskkill /F /IM "%SystemRoot%\System32\EOSNotify.exe" 1>NUL 2>NUL
  50. takeown /a /f "%SystemRoot%\System32\EOSNotify.exe" >NUL
  51. icacls "%SystemRoot%\System32\EOSNotify.exe" /grant administrators:D >NUL
  52. DEL /F /S /Q "%SystemRoot%\System32\EOSNotify.exe"
  53. )
  54. IF EXIST "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf" (
  55. ECHO.
  56. ECHO 删除 EOSNotifyMig.inf 文件...
  57. DEL /F /S /Q "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf"
  58. )
  59. TIMEOUT 3 >NUL
  60. ECHO.
  61. ECHO 优化EOSNotify 注册表设置...
  62. reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\SipNotify" /v "DontRemindMe" /t REG_DWORD /d "1" /f
  63. reg add "HKLM\Software\Policies\Microsoft\Windows\Gwx" /v "DisableGwx" /t REG_DWORD /d "1" /f
  64. reg add "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v "DisableOSUpgrade" /t REG_DWORD /d "1" /f
  65. reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\EOSNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f
  66. reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\SIPNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f
  67. reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "DiscontinueEOS" /t REG_DWORD /d "1" /f
  68. reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "Discontinue" /t REG_DWORD /d "1" /f
  69. reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "LastRunTimestamp" /f
  70. TIMEOUT 3 >NUL
  71. ECHO.
  72. ECHO 按任意键退出……
  73. PAUSE >NUL
  74. EXIT

懒人版下载:蓝奏云

本文由 木易梧桐's Blog 作者:metest 发表,转载请注明来源!

关键词:

发表评论